|
|
Bugfixes am Forum
Subdomains aktiviert
Counterscript entfernt
|
| |
|
 |
Referenzhandbuch |
 |
|
Referenzhandbuch
|
Kapitel 33
|
Blitz I/O
Es folgen die Ein- und Ausgabemöglichkeiten, die im BLITZMODUS erreichbar sind.
Anmerkung: Die Joyx-, Joyy-, Joyr- und
Joyb-Funktionen sind hier nicht aufgeführt. Die Funktionen sind aber im Blitzmodus anwendbar.
Befehl: BlitzKeys
Syntax: BlitzKeys On/Off
Modus: Blitz
BlitzKeys On ermöglicht die Übernahme von Tastatureingaben. Ist die Tastatureingabe
freigegeben, wird die Inkey$-Funktion zur Verarbeitung benutzt.
Beispiel:
BLITZ
BitMap 0,320,DispHeight,3
BitMapOutput 0
Slice 0,44,3
Show 0
BlitzKeys On
NPrint "Type Away..... (Click mouse to exit)"
While Joyb(0)=0
Print Inkey$
Wend
End
siehe auch: BlitzRepeat
Befehl: BlitzRepeat
Syntax: BlitzRepeat Delay,Speed
Modus: Blitz
BlitzRepeat erlaubt die Änderung der Tastatursteuerung.
Delay legt die Zeit in 50stel Sekunden fest, bevor eine gedrückte Taste wiederholt abgefragt wird.
Speed legt die Geschwindigkeit der Wiederholung in 50stel Sekunden fest.
Nur bei BlitzKeys On erreichbar.
siehe auch: BlitzKeys
Funktion: RawStatus
Syntax: RawStatus(Rawkey)
Modus: Blitz
Die Funktion prüft, ob eine Sondertaste, die mit Rawkey näher bezeichnet ist, gedrückt
wird oder nicht.
Übergabewert: gedrückt = -1, andernfalls = 0
Nur bei BlitzKeys On erreichbar.
Beispiel:
BLITZ
BitMap 0,320,DispHeight,3
BitMapOutput 0
Slice 0,44,3
Show 0
BlitzKeys On
NPrint "Click Mouse to exit..."
While Joyb(0)=0
Locate 0,1
Print "F1-Taste ist momentan:"
If RawStatus(80)
Print "Unten"
Else
Print "Oben "
EndIf
Wend
End
Befehl: Mouse
Syntax: Mouse On/Off
Modus: Blitz
Mouse On ermöglicht die Abfrage der Mausgeschwindigkeit und der Mausposition im Blitzmodus.
Beispiel:
BLITZ
BitMap 0,320,DispHeight,3
Slice 0,44,3
Show 0
Mouse On
While Joyb(0)=0
Line 160,100,MouseX,MouseY,1
Wend
End
Befehl: Pointer
Syntax: Pointer Spritenummer,Spritekanal
Modus: Blitz
Pointer ermöglicht es, ein Sprite im aktuellen Slice auf die Mausposition zu legen (Mauszeiger). Hierbei
müssen folgende Schritte nacheinander ausgeführt werden: Zuerst muß mit den Befehlen LoadShape
und GetaSprite ein Sprite angefertigt werden. Danach muß ein Slice eingerichtet werden, auf dem das
Sprite angezeigt wird.
Mouse On muß erfolgt sein, um die Mausdaten lesen zu können.
Zum Schluß übernimmt der Pointer-Befehl das Sprite als Mauszeiger.
Beispiel:
LoadShape 0,"MySprite" ;muß entweder 4 oder 16 Farben sein
LoadPalette 0,"MySprite",16 ;Palette aufnehmen
GetaSprite 0,0 ;Shape in Sprite umwandeln
BLITZ ;...
BitMap 0,320,DispHeight,3 ;Bitmap erzeugen
Slice 0,44,3 ;dem Slice...
Use Palette 0 ;werden Sprites hinzugefügt
Show 0 ;Bitmap zeigen
Mouse On ;Mouse im Blitz-Modus anschalten
Pointer 0,0 ;Zeiger hinzufügen
MouseWait
siehe auch: Mouse
Befehl: MouseArea
Syntax: MouseArea Minx,Miny,Maxx,Maxy
Modus: Blitz
MouseArea legt eine rechteckige Begrenzung der Mausbewegung auf dem Display fest.
Minx und Miny sind die Koordinaten der linken, oberen Ecke,
Maxx und Maxy für die untere, rechte Ecke des Bereichs.
Voreingestellt : Von 0,0 zu 320,200
Beispiel:
LoadShape 0,"MySprite" ;4- oder 16-farbig
LoadPalette 0,"MySprite",16 ;Palette des Sprites übernehmen
GetaSprite 0,0 ;Shape in Sprite umwandeln
BLITZ ;Blitz!
BitMap 0,320,DispHeight,3 ;Bitmap initialisieren
Slice 0,44,3 ;Slice erzeugen
Use Palette 0 ;und Farben des Sprites hinzufügen
Show 0 ;Bitmap zeigen
Mouse On ;Mouse im Blitz-Modus anschalten
MouseArea 80,50,240,150 ;Maus auf die 'Mitte' des Displays begrenzen
Pointer 0,0 ;Zeiger anpassen
MouseWait
Funktion: MouseX
Syntax: MouseX
Modus: Blitz
Diese Funktion gibt die horizontale Position der Maus zurück. Eine Anpassung erfolgt jede 50stel Sekunde. Ob ein Mauszeiger angezeigt
wird oder nicht, spielt keine Rolle.
MouseX funktioniert nur nach Ausführung von Mouse On.
Beispiel:
BLITZ ;gehe in den Blitz-Modus!
BitMap 0,320,DispHeight,3 ;eine Bitmap erstellen
Slice 0,44,3 ;und ein Slice
Show 0 ;Bitmap im Slice zeigen
While NOT Joyb(0) ;während der linke Mausknopf nicht gedrückt wird
VWait ;auf Vertical-Blank warten
Line 160,100,MouseX,MouseY,Rnd(7)+1 ;schöne Linien
Wend
siehe auch: MouseY, MouseXSpeed, MouseYSpeed
Funktion: MouseY
Syntax: MouseY
Modus: Blitz
Diese Funktion gibt die vertikale Position der Maus zurück. Eine Anpassungerfolgt jede 50stel Sekunde. Ob ein Mauszeiger angezeigt
wird oder nicht, spielt keine Rolle.
MouseY funktioniert nur nach Ausführung von Mouse On.
siehe auch: MouseX, MouseXSpeed, MouseYSpeed
Funktion: MouseXSpeed
Syntax: MouseXSpeed
Modus: Blitz
Diese Funktion übergibt die horizontale Mausgeschwindigkeit. Ist der Wert positiv, erfolgt eine Bewegung nach rechts, sonst nach
links. Ob der Mauszeiger angezeigt wird oder nicht, spielt keine Rolle. Mouse On wird vorher
benötigt. Die Funktion arbeitet nur nach jedem Vertical Blank. Deshalb muß zuvor ein VWait
ausgeführt werden oder ein Vertical Blank Interrupt erfolgen.
Funktion: MouseYSpeed
Syntax: MouseYSpeed
Modus: Blitz
Diese Funktion übergibt die vertikale Mausgeschwindigkeit. Ist der Wert positiv, erfolgt eine Bewegung nach rechts, sonst nach links.
Ob der Mauszeiger angezeigt wird oder nicht, spielt keine Rolle. Mouse On wird vorher benötigt.
Die Funktion arbeitet nur nach jedem Vertical Blank. Deshalb muß zuvor ein VWait ausgeführt werden
oder ein Vertical Blank Interrupt erfolgen.
siehe auch: MouseX, MouseY, MouseXSpeed
Befehl: LoadBlitzFont
Syntax: LoadBlitzFont Blitzfontnummer,Fontname.font$
Modus: Amiga
LoadBlitzFont erstellt ein Blitzfontobjekt. Blitzfonts werden zur Textausgabe auf eine Bitmap verwendet.
LoadBlitzFont lädt nur 8x8 Pixel Nichtproportionalfonts. Mit dem Parameter
Fontname.font$ wird der Name des zu ladenden Fonts festgelegt. Dieser Font muß sich im
FONTS:-Verzeichnis der Bootdisk befinden. Normalerweise wird der ROM-Topazfont benutzt.
Beispiel:
LoadBlitzFont 0,"Myfont.font" ;lade Blitzfont #0
Screen 0,3 ;ein Intuition-Bildschirm
ScreensBitMap 0,0 ;benutze seine Bitmap
BitMapOutput 0 ; Print auf diese Bitmap
Print "Hello - this is my font" ;Printe etwas
MouseWait
siehe auch: Use BlitzFont, Free BlitzFont, BitMapOutput
Befehl: Use BlitzFont
Syntax: Use BlitzFont Blitzfontnummer
Modus: Amiga/Blitz
Wenn Sie zwei oder mehr BlitzFonts geladen haben, können Sie mit Use BlitzFont einen der BlitzFonts zur
späteren Ausgabe auf die Bitmap wählen.
Beispiel:
LoadBlitzFont 0,"MyFont1.font" ;lade einen Blitzfont
LoadBlitzFont 1,"MyFont2.font" ;und einen anderen
Screen 0,3 ;ein Intuition-Bildschirm
ScreensBitMap 0,0 ;benutze seine Bitmap
BitMapOutput 0 ;Print umleiten
Use BlitzFont 0 ;benutze 1. Font
NPrint "This is My Font 1..." ;drucke etwas
Use BlitzFont 1 ;benutze 2. Font
NPrint "And this is My Font 2!" ;schreibe wieder etwas
MouseWait
siehe auch: LoadBlitzFont, Free BlitzFont
Befehl: Free BlitzFont
Syntax: Free BlitzFont Blitzfontnummer
Modus: Amiga/Blitz
Gibt den durch den Blitzfont Blitzfontnummer belegten Speicherbereich frei.
siehe auch: LoadBlitzFont, Use BlitzFont
Befehl: BitMapOutput
Syntax: BitMapOutput Bitmapnummer
Modus: Amiga/Blitz
BitMapOutput legt eine Bitmap Bitmapnummer zur Textausgabe mit
Print-Befehlen fest. BitMapOutput ist nur für den Blitzmodus gedacht, da
andere Textausgabeformen im Blitzmodus nicht verfügbar sind. Informationen zu den Fonts erhalten Sie unter
LoadBlitzFont.
Beispiel:
Screen 0,3 ;ein Intuition-Bildschirm
ScreensBitMap 0,0 ;benutze seine Bitmap
BitMapOutput 0 ;Print-Ausgaben nach dort senden
Print "Printing on a bitmap!" ;etwas drucken
MouseWait
siehe auch: LoadBlitzFont, Locate
Befehl: Colour
Syntax: Colour Vordergrundfarbe[,Hintergrundfarbe]
Modus: Amiga/Blitz
Colour erlaubt das Festlegen von Farben für die Textausgabe auf eine Bitmap.
Vordergrundfarbe bestimmt die Textfarbe, Hintergrundfarbe die
Texthintergrundfarbe. Es wird die Palette des aktuellen Slices (Blitzmodus) oder des aktuellen Screens (Amigamodus) benutzt.
Beispiel:
Screen 0,3 ;ein Intuition-Bildschirm
ScreensBitMap 0,0 ;benutze seine Bitmap
BitMapOutput 0 ;...
Locate 0,2
For k=0 To 7 ;Schleife 1
For J=0 To 7 ;Schleife 2
If k<>j ;ein paar Tricks
Colour k,j
Print "* "
EndIf
Next
Next
MouseWait
siehe auch: BitMapOutput
Befehl: Locate
Syntax: Locate X,Y
Modus: Amiga/Blitz
Locate legt die Koordinaten für die Cursorposition bei der Textausgabe mit
BitMapOutput fest. X legt die horizontale Zeichenposition fest, der Wert
muß durch 8 teilbar sein. Y legt die vertikale Zeichenposition fest, der Wert kann
Nachkommastellen enthalten. Als Beispiel: Ein Y-Wert von 1,5 setzt
den Cursor ein und ein halbes Zeichen unter dem oberen Rand der Bitmap. Der Locate-Befehl setzt den Cursor
auf die Bitmap, die mit dem BitMapOutput-Befehl festgelegt wurde.
Beispiel:
Screen 0,3 ;ein Intuition-Bildschirm
ScreensBitMap 0,0 ;benutze seine Bitmap
BitMapOutput 0 ;Prints auf diese Bitmap
For k=1 To 100 ;Schleifenstart
Locate Rnd(40),Rnd(DispHeight/8-7) ;zufällige Cursorposition
Colour Rnd(7)+1 ;zufällige Farbe
Print "*" ;ein Sternchen drucken
Next ;Schleifenende
MouseWait
siehe auch: BitMapOutput, CursX, CursY
Funktion: CursX
Syntax: CursX
Modus: Amiga/Blitz
Die Funktion gibt die horizontale Position des Cursors aus. Es ist möglich, die Position festzutellen, an der das nächste
Zeichen geprintet wird. Wiedergegeben wird der Wert von der Bitmap, die mit BitMapOutput festgelegt wurde.
Beispiel:
Screen 0,3 ;ein Intuition-Bildschirm
ScreensBitMap 0,0 ;benutze seine Bitmap
BitMapOutput 0 ;Print-Ausgaben dorthin umleiten
Locate 0,2 ;Bitmap-Cursor setzen
For k=1 To 16 ;Schleifenstart
While k>CursX ;Sternchen...
Print "* "
Wend
NPrint "" ;neue Zeile
Next
Funktion: CursY
Syntax: CursY
Modus: Amiga/Blitz
Die Funktion gibt die vertikale Position des Cursors aus. Es ist möglich, die Position festzutellen, an der das nächste Zeichen
geprintet wird. Wiedergegeben wird der Wert von der Bitmap, die mit BitMapOutput festgelegt wurde.
siehe auch: BitMapOutput, CursX, Locate
Befehl: BitMapInput
Syntax: BitMapInput
Modus: Blitz
Erlaubt die Anwendung von Edit$ und Edit im Blitzmodus. Zuvor muß
BlitzKeys On und BitMapOutput ausgeführt werden.
Beispiel:
Screen 0,3 ;ein Intuition-Bildschirm
ScreensBitMap 0,0 ;benutze seine Bitmap
BitMapOutput 0 ;Print-Ausgaben umleiten
BLITZ ;der berühmte Blitz-Modus!
BlitzKeys On ;Tastatur für den Blitz-Modus einschalten
BitMapInput ;Eingaben aus der Bitmap beziehen
Locate 0,2 ;Cursor setzen
a$=Edit$("Schreiben Sie etwas!!",40) ;ein paar Eingaben
siehe auch: BitMapOutput, BlitzKeys
|
|
|
|
|
|
|
